home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 05.zip / BS1 part 5 / IM_3.adf / Exec / piarc.LZH / rgb8wr.rexx < prev    next >
OS/2 REXX Batch file  |  1992-07-03  |  4KB  |  155 lines
  1. /*
  2.  * rgb8wr.rexx
  3.  *
  4.  *  Written by: Pete Patterson & Ben Williams
  5.  * Last Update: January 17, 1992
  6.  *         For: Black Belt Systems image processing series IM, IM F/c, and IP.
  7.  * ---------------------------------------------------------------------------
  8.  *    Revision: 1.01
  9.  */
  10.  
  11. /*
  12.  * open rexxsupport.library -- needed for some functions
  13.  */
  14. if ~show('L',"rexxsupport.library") then do
  15.   if addlib('rexxsupport.library',0,-30,0) then do
  16.       /* everything's ok */
  17.     end;
  18.   else do
  19.     say 'We Have A Library Problem, Unable To Load "rexxsupport.library"';
  20.     say 'Cannot operate rgb8wr.rexx without this library - sorry!';
  21.     exit 10;
  22.     end;
  23.   end;
  24.  
  25. /*
  26.  * This will automatically direct the script to the proper
  27.  * software, if it is running.
  28.  */
  29. prtnme = 'IP_Port'; /* assume Image Professional */
  30. if show('P','IP_Port') = 0 then do
  31.   if show('P','IM_Port') = 0 then do
  32.     say "Can't find image processor's ARexx port!!!"; /* not running? */
  33.     say "This script requires IP, IM or IM F/c to run!";
  34.     exit(20);
  35.     end;
  36.   else do
  37.     prtnme = 'IM_Port'; /* That's the thing about assumptions... */
  38.     end;                 /* We make em, user's break em.          */
  39.   end;
  40.  
  41.   /*
  42.    * This code attempts to read a file called "picmdpath" from REXX:
  43.    * If it can't find it, the script will assume that the commands
  44.    * associated with this PI Module are in "c:". If the file exists,
  45.    * the script will look in the path that is specified in the file.
  46.    * If you create this file, you MUST put a complete, correct path
  47.    * in it; if the commands are in a sub-directory, you have to put
  48.    * the trailing slash on the path (like, device:dir/).
  49.    * 
  50.    */
  51.   cmdpath = 'c:';
  52.   if open(fhandle,'rexx:picmdpath','read') then  /* open the file */
  53.     do
  54.       cmdpath = readln(fhandle);
  55.       call close(fhandle);  /* close the file    */
  56.     end
  57.  
  58. options;
  59. address;
  60.  
  61.   prevpath = 'ram:'; /* put user in ram to start with... */
  62.  
  63.   if show('C',rgbxpath) = 1 then do
  64.     prevpath = getclip(rgbxpath);
  65.     end;
  66.  
  67.   address(prtnme);
  68.   options results;
  69.   'current';
  70.   bufdata = result; /* get name of buffer, if there is one */
  71.   parse var bufdata bname ',' bnum ',' bx ',' by ',' btot ',' bmem ',' bparname ',' bparnum;
  72.   if bname ~= '<none>' then do
  73.     bufname = bname;
  74.     end;
  75.   'filerequest "'||prevpath||'","'||bufname||'","","Save RGBX"';
  76.   rgbxfile = result;
  77.   options;
  78.  
  79.   if rgbxfile = 'FR_CANCELLED' then do
  80.     address(prtnme);
  81.     'imtofront';
  82.     exit 0;
  83.     end;
  84.  
  85.   rgbxfile = expandfilename(rgbxfile);
  86.   thispath = gimmepath(rgbxfile);
  87.   call setclip(rgbxpath,thispath);
  88.  
  89.   address(prtnme);
  90.   options results;
  91.   'jackin';
  92.   jackadr = result;
  93.   options;
  94.  
  95.   'wbtofront';
  96.   address command cmdpath||'rgb8wr d'||jackadr||' "'||rgbxfile||'"';
  97.  
  98.   address(prtnme);
  99.   'imtofront';
  100.   address;
  101.  
  102.   exit 0;
  103.  
  104. /*
  105.  * gimmepath
  106.  *
  107.  * This takes the provided argument and sucks the path out of it, then
  108.  * returns that path to the caller, sans file name.
  109.  */
  110. gimmepath:
  111.   arg fullnamegx;
  112.     tempgx = reverse(fullnamegx);
  113.     lengx = length(fullnamegx);   /* get length of string */
  114.     slashdex = index(tempgx,'/'); /* first occurance of '/' from right */
  115.     colondex = index(tempgx,':');  /* first occurance of ':' from right */
  116.     seploc = 0; /* assumes current dir, no path supplied */
  117.     if slashdex ~= 0 then do /* we assume we are in a DIR */
  118.       seploc = (lengx - slashdex)+1;
  119.       end;
  120.     else do
  121.       if colondex ~= 0 then do /* we assume we are on a device */
  122.         seploc = (lengx - colondex)+1;
  123.         end;
  124.       end;
  125.   gxname = substr(fullnamegx,seploc+1); /* if you ever need it */
  126.   gxpath = left(fullnamegx,seploc);
  127.   return(gxpath);
  128.  
  129. /*
  130.  * Since this script can't be expected to know where the CD of the user
  131.  * is when this cmd is invoked, we have to check the path the user
  132.  * provides - if it's not specified right from a root, then we have
  133.  * to make it a complete specification from the root.
  134.  */
  135. expandfilename:
  136.   parse arg jfile;
  137.   if index(jfile,':') = 0 then do
  138.     curdir = pragma(D);
  139.     if right(curdir,1) ~= ':' then do
  140.       if right(curdir,1) ~= '/' then do
  141.         if curdir ~= '' then do
  142.           curdir = curdir || '/';
  143.           end;
  144.         end;
  145.       end;
  146.     jfile = curdir||jfile;
  147.     end;
  148.   return(jfile);
  149.  
  150. rvalue:
  151.   wordnum = c2d(readch(fhandle,1)) * 256;
  152.   wordnum = wordnum + c2d(readch(fhandle,1));
  153.   return wordnum;
  154.  
  155.